移動平均は、一定本数の価格の平均をとったものです。平均をとることで価格変動が平滑化されますが、平均をとる期間によって平滑化の度合いが変わってきます。異なる期間の移動平均線は交差するため、これを仕掛けシグナルと見なします。

短期移動平均の方が価格により速く反応するので、価格が上昇して短期移動平均線が長期移動平均線を上抜けたとき（ゴールデンクロス）に買いシグナル、価格が下落して短期移動平均線が長期移動平均線を下抜けたとき（デッドクロス）に売りシグナルを出します。

仕掛けシグナル

<aside> 💡 買いシグナル：２本前から１本前にかけて短期移動平均線が長期移動平均線を下から上に交差したとき 売りシグナル：２本前から１本前にかけて短期移動平均線が長期移動平均線を上から下に交差したとき

</aside>

コード

//共通ライブラリ
#include "LibEA.mqh"

sinput double Lots = 0.1; //売買ロット数

//ティック時実行関数
void Tick()
{
   int sig_entry = EntrySignal(); //仕掛けシグナル
   //成行売買
   MyOrderSendMarket(sig_entry, sig_entry, Lots);
}

input int FastMAPeriod = 20; //短期移動平均の期間
input int SlowMAPeriod = 50; //長期移動平均の期間

//仕掛けシグナル関数
int EntrySignal()
{
   //１本前と２本前の移動平均
   double FastMA1 = iMA(_Symbol, 0, FastMAPeriod, 0, MODE_SMA, PRICE_CLOSE, 1);
   double FastMA2 = iMA(_Symbol, 0, FastMAPeriod, 0, MODE_SMA, PRICE_CLOSE, 2);
   double SlowMA1 = iMA(_Symbol, 0, SlowMAPeriod, 0, MODE_SMA, PRICE_CLOSE, 1);
   double SlowMA2 = iMA(_Symbol, 0, SlowMAPeriod, 0, MODE_SMA, PRICE_CLOSE, 2);

   int ret = 0; //シグナルの初期化

   //買いシグナル
   if(FastMA2 <= SlowMA2 && FastMA1 > SlowMA1) ret = 1;
   //売りシグナル
   if(FastMA2 >= SlowMA2 && FastMA1 < SlowMA1) ret = -1;

   return ret; //シグナルの出力
}

説明

移動平均は、[iMA()](<https://toyolab-fx.notion.site/iMA-8f3239ece7cc43598d315d391258ee05>)というテクニカル指標関数で求められます。

移動平均の期間として、別途宣言した変数FastMAPeriod、あるいはSlowMAPeriodをma_periodの引数に代入します。

終値を対象とした単純移動平均の場合、applied_priceの引数にPRICE_CLOSEを、ma_methodの引数にMODE_SMAを代入します。

2本前の短期移動平均FastMA2、長期移動平均SlowMA2、1本前の短期移動平均FastMA1、長期移動平均SlowMA1の大小関係でシグナルを判定します。